Cooking with CQL Q&As

Session 52 - Thursday, March 25, 2021

# Queries in CQL

**Q:** How do you write an expression to return all immune check inhibitor (ICI) therapies, over a 12-month period, where the ICI administration dates are eight weeks or less between administration?

**A:** The intent is that the administrations are eight weeks or less apart. There is a string of data points that are no more than eight weeks apart until the endpoint. The endpoint could be where the ICI therapy is greater than eight weeks from the previous administration, the end of the one-year treatment period from the start of ICI therapy, or the end of the measurement period.

|  |  |
| --- | --- |
| define "ICI Starts Within 8 weeks Interval": | |
|  | "ICI Therapy" Therapy |
|  | without "ICI Therapy" PriorTherapy |
|  | such that PriorTherapy !~ Therapy |
|  | and PriorTherapy.relevantPeriod starts 57 days or more before day of start of Therapy.relevantPeriod |
|  |  |
|  | define "Start of ICI": |
|  | Min("ICI Starts Within 8 weeks Interval" ICITherapy |
|  | return start of ICITherapy.relevantPeriod |
|  | ) |
|  |  |
|  | define "End of ICI": |
|  | Min({ |
|  | end of "Measurement Period", "Start of ICI" + 1 year, Max("ICI Starts Within 8 weeks Interval" Therapy |
|  | return |
|  | end of Therapy.relevantPeriod |
|  | )} |
|  | ) |

**Q:** When working with a measure that is looking for patients for whom thyroid stimulating hormone (TSH or T4) testing is performed at least once every 8 weeks while receiving immune check inhibitor (ICI) therapy for a maximum duration of 1 year from the start of ICI therapy, how can the data be sorted into relevant bins while looking for an abnormal TSH or T4 result?

**A:** For each TSH or T4 lab test performed, there should be a laboratory test result returned to the eight-week bin that the lab result is associated with. Lab results are assigned to a bin by the result date being within the bin boundaries. Bins start with the beginning of ICI therapy, indexed 1 through x, where bin 1 is from zero to eight weeks after the start of ICI therapy and x is the end of that eight-week period. The subsequent bin, e.g., bin 2, starts at the previous bin’s ending point and goes through the next eight-week period.

The bin intervals could be constructed as follows:

Bin 1: 0 weeks <= x < 8 weeks

Bin 2: 8 weeks <= x < 16 weeks

Bin 3: 16 weeks <= x < 24 weeks

Bin 4: 24 weeks <= x < 32 weeks

Bin 5: 32 weeks <= x < 40 weeks

Bin 6: 40 weeks <= x < 48 weeks

Bin 7: 48 weeks <= x < 56 weeks

If the patient stops therapy before exactly 1 year from therapy start date, look for 1 TSH test within the bin for which the patient therapy end date falls. If the patient is still on therapy when they reach 1 year from therapy start date, look for a final TSH test within bin 7 (week 48-56). If the patient is on therapy for less than 8 weeks, look for 1 TSH test within bin 1.

define "ICI Therapy Bins":

expand Interval[1, "Required Bins"]

Then use the bin numbers to construct 8-week intervals, beginning at the start of ICI:

define "ICI Therapy Bin Periods":

"ICI Therapy Bins" Bin

return Interval["Start of ICI" + ((Bin - 1) \* 8 weeks), "Start of ICI" + (Bin \* 8 weeks))

Then look for bin periods that contain the expected tests:

define "ICI Therapy Bin Periods with Required Test Lab":

"ICI Therapy Bin Periods" Period

with "Test Lab" LT

such that LT.relevantDatetime during Period

Then in the numerator:

define "Required Bins":

(weeks between "Start of ICI" and "End of ICI") div 8

define "Proposed Numerator":

Count("ICI Therapy Bin Periods with Required Test Lab") = "Required Bins"

# Measure Logic in CQL

**Q:** Using Quality Data Model (QDM) 5.5 and encounter-based logic, we are looking for encounters where bleeding events occur during both the encounter and within 5 days following an anticoagulant medication administration. If we use the 'from' and 'let' query, does that eliminate an occurrence issue to ensure that all three things (qualifying encounter, anticoagulant medication administration, and bleeding event diagnosis) occurred on the one encounter? There could be multiple qualifying encounters and some of these could happen across encounters but not all occurring on the same exact encounter.

**A:** The keyword 'from' followed by multiple sources of qualifying encounters, bleeding diagnoses, and administered anticoagulant medications specifies a “multi-source query”. In a multi-source query, conceptually, all combinations of elements from each of the input sources are considered. This particular query has 3 sources, so the query ranges over “triples” representing the combined elements from each source. The elements from each source can be referenced within the query by its alias name. The Global "HospitalizationWithObservation" function expands the time constraints of a "Qualifying Encounters" inpatient hospitalization to include an immediately preceding Observation and/or Emergency Department stay. The 'where' clause filters the results to encounters where the bleeding diagnosis started during the “HospitalizationWithObservation” period of the encounter. The where clause also filters the results to encounters where there is an anticoagulant medication administered during the hospitalization period of the encounter and the bleeding diagnosis starts 120 hours or less after the anticoagulant medication was administered. Note that if the where clause does not constrain the results, all possible combinations of the input sources will be returned.

|  |  |
| --- | --- |
| define "Encounters With Critical Bleeding Diagnosis": | |
|  | from |
|  | "Qualifying Encounters" QualifyingEncounter, |
|  | ["Diagnosis": "Bleeding at Critical Site"] BleedingDiagnosis, |
|  | ["Medication, Administered": "Anticoagulants for VTE Prophylaxis"] AnticoagulantMedication |
|  | where BleedingDiagnosis.prevalencePeriod during Global."HospitalizationWithObservation" ( QualifyingEncounter ) |
|  | and BleedingDiagnosis.prevalencePeriod starts 120 hours or less after AnticoagulantMedication.relevantDatetime |
|  | and AnticoagulantMedication.relevantDatetime during Global."HospitalizationWithObservation" ( QualifyingEncounter ) |
|  | return QualifyingEncounter |